{
  haskellPackages,
  haskell,
  zlib,
  watchexec,
  wasm32-wasi-cabal,
  wasm32-wasi-ghc,
  writeShellApplication,
  nodejs,
  python3,
}:
haskellPackages.developPackage {
  name = "numbersquare";
  root = ./.;
  modifier =
    let
      addBuildTools =
        drv:
        haskell.lib.addBuildTools drv (
          [
            watchexec
            wasm32-wasi-cabal
            wasm32-wasi-ghc
            nodejs
            (writeShellApplication {
              name = "dev-server";
              text = ''
                python -m http.server -d ./out
              '';
              runtimeInputs = [ python3 ];
            })
          ]
          ++ (with haskellPackages; [
            fourmolu
            haskell-language-server
            cabal-install
            hpack
            ghcid
            cabal-fmt
            hoogle
          ])
        );
      addExtraLibraries = drv: haskell.lib.addExtraLibraries drv [ zlib ];
    in
    drv: addExtraLibraries (addBuildTools drv);
}